Showing pcg32.pl (raw)

  1. #!/usr/bin/env perl
  2.  
  3. ###############################################################################
  4. # Two implementations of PCG32. One in native Perl with no dependencies, and
  5. # one that uses Math::Int64. Surprisingly the native version is significantly
  6. # faster.
  7. #
  8. # A lot of work was done here to mimic how C handles overflow multiplication
  9. # on large uint64_t numbers. Perl converts scalars that are larger than 2^64-1
  10. # to floating point on the backend. We do *NOT* want that for PCG, because
  11. # PCG (and more PRNGs) rely on overflow math to do their magic. We utilize
  12. # 'use integer' to force Perl to do all math with regular 64bit values. When
  13. # overflow occurs Perl likes to convert those values to negative numbers. In
  14. # the original C all math is done with uint64_t, so we have to convert the
  15. # IV/negative numbers back into UV/unsigned (positive) values. PCG also uses
  16. # some uint32_t variables internally, so we mimic that by doing the math in
  17. # 64bit and then masking down to only the 32bit number.
  18. #
  19. ###############################################################################
  20. #
  21. # Original C code from: https://www.pcg-random.org/download.html
  22. #
  23. # typedef struct { uint64_t state;  uint64_t inc; } pcg32_random_t;
  24. #
  25. # uint32_t pcg32_random_r(pcg32_random_t* rng) {
  26. #     uint64_t oldstate = rng->state;
  27. #     // Advance internal state
  28. #     rng->state = oldstate * 6364136223846793005ULL + (rng->inc|1);
  29. #     // Calculate output function (XSH RR), uses old state for max ILP
  30. #     uint32_t xorshifted = ((oldstate >> 18u) ^ oldstate) >> 27u;
  31. #     uint32_t rot = oldstate >> 59u;
  32. #     return (xorshifted >> rot) | (xorshifted << ((-rot) & 31));
  33. # }
  34. #
  35. ###############################################################################
  36.  
  37. use strict;
  38. use warnings;
  39. use v5.16;
  40. use Math::Int64 qw(uint64 uint64_to_number);
  41. use Getopt::Long;
  42. use Test::More;
  43.  
  44. ###############################################################################
  45. ###############################################################################
  46.  
  47. my $debug = 0;
  48. my $s1    = 15939250660798104135; # Default 64bit seed1
  49. my $s2    = 3988331200502121509;  # Default 64bit seed2
  50. my $seeds = [];
  51.  
  52. GetOptions(
  53.     'debug'      => \$debug,
  54.     'seed1=i'    => \$s1,
  55.     'seed2=i'    => \$s2,
  56.     'random'     => \&randomize_seeds,
  57.     'unit-tests' => \&run_unit_tests,
  58. );
  59.  
  60. my $num = $ARGV[0] || 8;
  61. my ($seed1, $seed2);
  62.  
  63. print color('yellow', "Seeding PRNG with: $s1 / $s2\n\n");
  64.  
  65. $seeds = [$s1, $s2];
  66. for (my $i = 1; $i <= $num; $i++) {
  67.     my $num32 = pcg32_perl($seeds);
  68.     my $num64 = pcg64_perl($seeds);
  69.     printf("%2d) %10u / %20u\n", $i, $num32, $num64);
  70. }
  71.  
  72. ################################################################################
  73. ################################################################################
  74. ################################################################################
  75.  
  76. #my $seeds = [12, 34];
  77. #my $rand  = pcg32_perl($seeds);
  78. sub pcg32_perl {
  79.     # state/inc are passed in by reference
  80.     my ($s) = @_;
  81.  
  82.     my $oldstate = $s->[0]; # Save original state
  83.  
  84.     # We use interger math because Perl converts to floats any scalar
  85.     # larger than 2^64. PCG *requires* 64bit uint64_t math, with overflow,
  86.     # to calculate correctly. We have to unconvert the overflowed number
  87.     # from an IV to UV after the big math
  88.     use integer;
  89.     $s->[0] = $oldstate * 6364136223846793005 + ($s->[1] | 1);
  90.     $s->[0] = iv_2_uv($s->[0]);
  91.     no integer;
  92.  
  93.     my $xorshifted = (($oldstate >> 18) ^ $oldstate) >> 27;
  94.     $xorshifted    = $xorshifted & 0xFFFFFFFF; # Convert to uint32_t
  95.  
  96.     my $rot = ($oldstate >> 59);
  97.  
  98.     # -$rot on a uint32_t is the same as (2^32 - $rot)
  99.     my $invrot = 4294967296 - $rot;
  100.     my $ret    = ($xorshifted >> $rot) | ($xorshifted << ($invrot & 31));
  101.  
  102.     # Convert to uint32_t
  103.     $ret = $ret & 0xFFFFFFFF;
  104.  
  105.     if ($debug) {
  106.         # $oldstate is the state at the start of the function and $inc
  107.         # doesn't change so we can print out the initial values here
  108.         print color('orange', "State : $oldstate/$s->[1]\n");
  109.         print color('orange', "State2: $s->[0]\n");
  110.         print color('orange', "Xor   : $xorshifted\n");
  111.         print color('orange', "Rot   : $rot\n");
  112.     }
  113.  
  114.     return $ret;
  115. }
  116.  
  117. # During large integer math when a UV overflows and wraps back around
  118. # Perl casts it as a IV value. For the purposes of PCG we need that
  119. # wraparound math to stay in place. We need uint64_t all the time.
  120. sub iv_2_uv {
  121.     my $x = $_[0];
  122.  
  123.     # Flip it from a IV (signed) to a UV (unsigned)
  124.     # use Devel::Peek; Dump($var) # See the internal Perl type
  125.     if ($x < 0) {
  126.         no integer;
  127.         $x += 18446744073709551615;
  128.         $x += 1;
  129.     }
  130.  
  131.     return $x;
  132. }
  133.  
  134. # To get a 64bit number from PCG32 you create two different generators
  135. # and combine the results into a single 64bit value. All the examples
  136. # online show 1 for the inc/seed2 value. I'm not sure why that is, but
  137. # I copied it for my implementation.
  138. #
  139. #my $seeds = [12, 34];
  140. #my $rand  = pcg64_perl($seeds);
  141. sub pcg64_perl {
  142.     my ($s) = @_;
  143.  
  144.     # Build a new object to send to each pcg32 instance
  145.     my $inc = 1; # Can be any 64bit value
  146.     my $one = [$s->[0], $inc];
  147.     my $two = [$s->[1], $inc];
  148.  
  149.     # Get two 32bit ints
  150.     my $high = pcg32_perl($one);
  151.     my $low  = pcg32_perl($two);
  152.  
  153.     # We copy the data back into the original object
  154.     $s->[0] = $one->[0];
  155.     $s->[1] = $two->[0];
  156.  
  157.     # Combine the two 32bits into one 64bit int
  158.     my $ret = ($high << 32) | $low;
  159.  
  160.     return $ret;
  161. }
  162.  
  163. #my $seeds = [uint64(12), uint64(34)];
  164. #my $rand  = pcg32_math64($seeds);
  165. sub pcg32_math64 {
  166.     # state/inc are passed in by reference
  167.     my ($s) = @_;
  168.  
  169.     my $oldstate = $s->[0];
  170.     $s->[0]      = $oldstate * 6364136223846793005 + ($s->[1] | 1);
  171.  
  172.     my $xorshifted = (($oldstate >> 18) ^ $oldstate) >> 27;
  173.     $xorshifted    = $xorshifted & 0xFFFFFFFF; # Convert to uint32_t
  174.  
  175.     my $rot    = $oldstate >> 59;
  176.     my $invrot = 4294967296 - $rot;
  177.  
  178.     my $ret = ($xorshifted >> $rot) | ($xorshifted << ($invrot & 31));
  179.     $ret    = $ret & 0xFFFFFFFF; # Convert to uint32_t
  180.  
  181.     $ret = uint64_to_number($ret);
  182.  
  183.     if ($debug) {
  184.         # $oldstate is the state at the start of the function and $inc
  185.         # doesn't change so we can print out the initial values here
  186.         print color('orange', "State : $oldstate/$s->[1]\n");
  187.         print color('orange', "State2: $s->[0]\n");
  188.         print color('orange', "Xor   : $xorshifted\n");
  189.         print color('orange', "Rot   : $rot\n");
  190.     }
  191.  
  192.     return $ret;
  193. }
  194.  
  195. ###############################################################################
  196. ###############################################################################
  197.  
  198. # String format: '115', '165_bold', '10_on_140', 'reset', 'on_173', 'red', 'white_on_blue'
  199. sub color {
  200.     my ($str, $txt) = @_;
  201.  
  202.     # If we're NOT connected to a an interactive terminal don't do color
  203.     if (-t STDOUT == 0) { return $txt || ""; }
  204.  
  205.     # No string sent in, so we just reset
  206.     if (!length($str) || $str eq 'reset') { return "\e[0m"; }
  207.  
  208.     # Some predefined colors
  209.     my %color_map = qw(red 160 blue 27 green 34 yellow 226 orange 214 purple 93 white 15 black 0);
  210.     $str =~ s|([A-Za-z]+)|$color_map{$1} // $1|eg;
  211.  
  212.     # Get foreground/background and any commands
  213.     my ($fc,$cmd) = $str =~ /^(\d{1,3})?_?(\w+)?$/g;
  214.     my ($bc)      = $str =~ /on_(\d{1,3})$/g;
  215.  
  216.     if (defined($fc) && int($fc) > 255) { $fc = undef; } # above 255 is invalid
  217.  
  218.     # Some predefined commands
  219.     my %cmd_map = qw(bold 1 italic 3 underline 4 blink 5 inverse 7);
  220.     my $cmd_num = $cmd_map{$cmd // 0};
  221.  
  222.     my $ret = '';
  223.     if ($cmd_num)      { $ret .= "\e[${cmd_num}m"; }
  224.     if (defined($fc))  { $ret .= "\e[38;5;${fc}m"; }
  225.     if (defined($bc))  { $ret .= "\e[48;5;${bc}m"; }
  226.     if (defined($txt)) { $ret .= $txt . "\e[0m";   }
  227.  
  228.     return $ret;
  229. }
  230.  
  231. sub randomize_seeds {
  232.     print color(51, "Using random seeds\n");
  233.  
  234.     $s1 = perl_rand64();
  235.     $s2 = perl_rand64();
  236. }
  237.  
  238. sub perl_rand64 {
  239.     my $low  = int(rand() * (2**32-1));
  240.     my $high = int(rand() * (2**32-1));
  241.  
  242.     my $ret = ($high << 32) | $low;
  243.  
  244.     return $ret;
  245. }
  246.  
  247. # Creates methods k() and kd() to print, and print & die respectively
  248. BEGIN {
  249.     if (eval { require Data::Dump::Color }) {
  250.         *k = sub { Data::Dump::Color::dd(@_) };
  251.     } else {
  252.         require Data::Dumper;
  253.         *k = sub { print Data::Dumper::Dumper(\@_) };
  254.     }
  255.  
  256.     sub kd {
  257.         k(@_);
  258.  
  259.         printf("Died at %2\$s line #%3\$s\n",caller());
  260.         exit(15);
  261.     }
  262. }
  263.  
  264. # Run a test with a given seed and return a string of the results
  265. sub quick_test32 {
  266.     my $seed = $_[0];
  267.  
  268.     my @data = ();
  269.     for (my $i = 0; $i < 4; $i++) {
  270.         my $num = pcg32_perl($seed);
  271.         push(@data, $num);
  272.     }
  273.  
  274.     my $ret = join(", ", @data);
  275.     return $ret;
  276. }
  277.  
  278. sub quick_test64 {
  279.     my $seed = $_[0];
  280.  
  281.     my @data = ();
  282.     for (my $i = 0; $i < 4; $i++) {
  283.         my $num = pcg64_perl($seed);
  284.         push(@data, $num);
  285.     }
  286.  
  287.     my $ret = join(", ", @data);
  288.     return $ret;
  289. }
  290.  
  291. sub run_unit_tests {
  292.     # Seeds < 2**32
  293.     cmp_ok(quick_test32([11, 22])      , 'eq', '0, 1425092920, 3656087653, 1104107026');
  294.     cmp_ok(quick_test32([33, 44])      , 'eq', '0, 3850707138, 2930351490, 1110209703');
  295.     cmp_ok(quick_test32([55, 66])      , 'eq', '0, 1725101930, 224698313, 2870828486');
  296.     cmp_ok(quick_test32([12345, 67890]), 'eq', '0, 8251198, 44679150, 3046830521');
  297.     cmp_ok(quick_test32([9999, 9999])  , 'eq', '0, 521292032, 3698775557, 199399470');
  298.  
  299.     cmp_ok(quick_test64([11, 22])      , 'eq', '0, 6120727489207695446, 7904312005358798897, 14733674221366828425');
  300.     cmp_ok(quick_test64([33, 44])      , 'eq', '0, 16538661225628040268, 5269891931295187491, 5495286771333204711');
  301.     cmp_ok(quick_test64([55, 66])      , 'eq', '0, 7409256372025208996, 8212781881022671801, 8831782971077082788');
  302.     cmp_ok(quick_test64([12345, 67890]), 'eq', '0, 35438628484449140, 42862460907032573, 519456495312580246');
  303.     cmp_ok(quick_test64([9999, 9999])  , 'eq', '0, 2238932229626677504, 14236525402126437484, 10387246122801752400');
  304.  
  305.     # Seeds > 2**32
  306.     cmp_ok(quick_test32([42862460907032573, 519456495312580246])    , 'eq', '319349001, 562730850, 2229409754, 561058538');
  307.     cmp_ok(quick_test32([6120727489207695446, 7904312005358798897]) , 'eq', '635930912, 2099303707, 1638577555, 1426136496');
  308.     cmp_ok(quick_test32([4841811808465514507, 7141191103728083377]) , 'eq', '1986408540, 4264878569, 3066617590, 731859269');
  309.  
  310.     cmp_ok(quick_test64([42862460907032573, 519456495312580246])    , 'eq', '1371593519175525487, 17623029558467823369, 17850014000156247978, 768534907509427587');
  311.     cmp_ok(quick_test64([6120727489207695446, 7904312005358798897]) , 'eq', '2731302471965979098, 3465889473135782122, 4841811808465514507, 7141191103728083377');
  312.     cmp_ok(quick_test64([4841811808465514507, 7141191103728083377]) , 'eq', '8531559717926221063, 6031125200978744796, 3704366926003160989, 5594521440717127703');
  313.  
  314.     done_testing();
  315.     exit(0);
  316. }
  317.  
  318. # vim: tabstop=4 shiftwidth=4 noexpandtab autoindent softtabstop=4